amiga-news ENGLISH VERSION
.
Links| Forum| Kommentare| News melden
.
Chat| Umfragen| Newsticker| Archiv
.

amiga-news.de Forum > Amiga, AmigaOS 4 > Suche eMail-Tool... [ - Suche - Neue Beiträge - Registrieren - Login - ]

-1- [ - Beitrag schreiben - ]

20.09.2004, 17:37 Uhr

Falcon
Posts: 3544
Nutzer
Hi Leute,

ich suche ein Tool, mit dem man eMails auf's handy schicken kann.
Eine entsprechende Mailaddi habe ich.
Mit YAM geht das zwar, aber lieber wäre mir ein Tool, das ich in Scripte einbauen kann.
So ähnlich wie ECHO oder SAY oder sowas.
Wenn ich also z.B. sagen könnte 'ECHO @blablabla@bla,de Wichtige Meldung...' das würde mir reichen.

In YAM müßte ich erst ein Script schreiben, das u.A. die Sig löscht, da nur die Betreffzeile gesendet werden kann.

Gibt es sowas ?

Danke,

Falcon.
--
Che-Hoa Yuin sagt:
Der Amiga kann alles, was man zum Arbeiten braucht...
... was er nicht kann, braucht man auch nicht !!!!!!!

Meine Homepage: http://www.elasticimages.de.vu

[ - Antworten - Zitieren - Direktlink - ]

20.09.2004, 18:17 Uhr

Robin
Posts: 1056
Nutzer
RxSocket Library und Arexx ?

/* */

l="rmh.library";if ~show("L",l) then;if ~addlib(l,0,-30) then exit
l="rxsocket.library";if ~show("L",l) then;if ~addlib(l,0,-30) then exit

host="<DOMAIN>"
pass="<PASSWORT>"
email="<ABSENDER EMAIL>"
destemail="<EMPFAENGER EMAIL>"
subject="Warnung Test !"
message="Dies ist ein Test"

sock = OpenConnection("tcp","pop3",host)
if sock<0 then do
select
when sock==-3 then
say "pop3: service pop3 not found"
when sock==-2 then
say "pop3: host <" || host || "> not found (" || HostErrorno() || ")"
when sock==-1 then
say "pop3: unable to connect pop3 service at <" || host || "> (" || errno() || ")"
end
exit
end

CRLF = "D"x || "A"x
ENDMULTI = "."
call rec("SINGLE")

sock = OpenConnection("tcp",25,host)
call rec("SINGLE")
call sen("HELO" host)
call rec("SINGLE")
call sen("mail from:" email)
call rec("SINGLE")
call sen("rcpt to:" destemail)
call rec("SINGLE")
call sen("data")
call rec("SINGLE")
call sen("Subject: "||subject)
call sen(message)
call sen(".")
call rec("SINGLE")

exit

/******************************************************/
sen:
parse arg string
string = string || CRLF
res = send(sock,string)
if res~=length(string) then do
say "pop3: send error (" || errno() || ")"
exit
end
return
/******************************************************/
rec:
parse arg comType
first=1
do forever
len = recvline(sock,"BUF",256)
if len<0 then do
say "pop3: recv error (" || errno() || ")"
exit
end
parse var buf buf "D"x
if first then do
if left(buf,1)=="-" then do
parse var buf "-ERR " text
say " Error from server" text
return
end
parse var buf buf "+OK " buf
first=0
end
if comType=="MULTI" then
if buf=ENDMULTI then return
if comType=="SINGLE" then return
end
/******************************************************/
--
Bild: http://my.morphosi.net/cgi-bin/mnet.pl?mode=forum&showsmilie=baby2 AMIGA-News Babysitter gesucht !

[ Dieser Beitrag wurde von Robin am 20.09.2004 editiert. ]

[ - Antworten - Zitieren - Direktlink - ]

20.09.2004, 18:29 Uhr

Falcon
Posts: 3544
Nutzer
Hey, das ging ja schnell. DANKE !
Aber was muß ich bei HOST und PASSWORD eintragen ?

Ach ja, ich gehe über DSL ins Netz, bin also on, sobald der rechner an ist.
Ansonsten ist das genau das, was ich gesucht habe. AREXX RULEZ !

Ciao,

Falcon.
--
Che-Hoa Yuin sagt:
Der Amiga kann alles, was man zum Arbeiten braucht...
... was er nicht kann, braucht man auch nicht !!!!!!!

Meine Homepage: http://www.elasticimages.de.vu

[ - Antworten - Zitieren - Direktlink - ]

20.09.2004, 18:49 Uhr

Robin
Posts: 1056
Nutzer
Na, du must dem Skript schon verraten an welchen Server
es die Email schicken soll ;) Hier ist es zb host="amiganiac.net".
Das Passwort und der User sind die POP3-Daten.
Das Skript baut zuerst eine POP3-Verbindung auf, da es
Server gibt, die es erst danach erlauben Mails per SMTP zu
versenden. Falls du noch SMTP-Auth brauchst muss ich erst nochmal
suchen wie das geht.

Arexx ist einfach toll :)

--
Bild: http://my.morphosi.net/cgi-bin/mnet.pl?mode=forum&showsmilie=baby2 AMIGA-News Babysitter gesucht !

[ - Antworten - Zitieren - Direktlink - ]

20.09.2004, 19:13 Uhr

thomas
Posts: 7716
Nutzer
Findest du das nicht etwas kompliziert, mit zwei zusätzlichen Libraries und dem ganzen Zeugs ?

Hier ist ein einfacheres Beispiel:

code:
/* rexx */

server  = "mailto.t-online.de"
port    = 25
domain  = "t-online.de"
from    = "thomas-rapp@t-online.de"
to      = "thomas-rapp@web.de"
subject = "test mail mit smtp"
lines = 7
line.1 = "Hallo !"
line.2 = ""
line.3 = "Dies ist ein Test."
line.4 = ""
line.5 = "Gruß Thomas"
line.6 = "-- "
line.7 = "http://thomas-rapp.homepage.t-online.de"
 
 

if Open(tcp,"tcp:"server"/"port,write) then do
	say ReadLn(tcp)
	call WriteLn tcp,'HELO' domain
	say ReadLn(tcp)
	call WriteLn tcp,'MAIL From:<'from'>'
	say ReadLn(tcp)
	call WriteLn tcp,'RCPT To:<'to'>'
	say ReadLn(tcp)
	call WriteLn tcp,'DATA'
	say ReadLn(tcp)
	call WriteLn tcp,'From: <'from'>'
	call WriteLn tcp,'To: <'to'>'
	call WriteLn tcp,'Subject:' subject
	call WriteLn tcp,''
	do i=1 to lines
		call WriteLn tcp,line.i
	end
	call WriteLn tcp,''
	call WriteLn tcp,'.'
	say ReadLn(tcp)
	call WriteLn tcp,'QUIT'
	say ReadLn(tcp)
	call Close(tcp)
end


Die Zeilen mit "say" kann man auch weglassen, die geben nur die Antworten aus, falls man einen Fehler sucht.

Gruß Thomas

P.S.: um die SMTP-Befehle zu verstehen, solltest du dir mal den SMTP-Explorer vom PC-Magazin herunterladen (für Windows), der erklärt sehr schön, wie das Senden einer Mail abläuft.

--
Email: thomas-rapp@web.de
Home: home.t-online.de/home/thomas-rapp/

[ Dieser Beitrag wurde von thomas am 20.09.2004 editiert. ]

[ - Antworten - Zitieren - Direktlink - ]

20.09.2004, 19:36 Uhr

Robin
Posts: 1056
Nutzer
das ist natuerlich eleganter :)
Gibt es eigentlich irgendwo eine Anleitung zu diesem
TCP: Zeugs ? Gesehen hab ich es schon oefter, aber noch nicht so
richtig verstanden ;)
--
Bild: http://my.morphosi.net/cgi-bin/mnet.pl?mode=forum&showsmilie=baby2 AMIGA-News Babysitter gesucht !

[ - Antworten - Zitieren - Direktlink - ]

20.09.2004, 21:00 Uhr

Falcon
Posts: 3544
Nutzer
Danke für Eure Antworten.
Das Script von Thomas sieht wirklich einfacher aus.
Probiere ich gleich mal aus.

Danke an alle,

Falcon.
--
Che-Hoa Yuin sagt:
Der Amiga kann alles, was man zum Arbeiten braucht...
... was er nicht kann, braucht man auch nicht !!!!!!!

Meine Homepage: http://www.elasticimages.de.vu

[ - Antworten - Zitieren - Direktlink - ]

20.09.2004, 21:25 Uhr

thomas
Posts: 7716
Nutzer
Zitat:
Original von Robin:
das ist natuerlich eleganter :)
Gibt es eigentlich irgendwo eine Anleitung zu diesem
TCP: Zeugs ? Gesehen hab ich es schon oefter, aber noch nicht so
richtig verstanden ;)



Müßte bei AmiTCP oder Genesis dabei sein oder in der Miami-Doku.

Im Prinzip öffnest du eine Datei namens TCP:<server>/<port> oder TCP:<port>

Das erste baut eine Telnet-Verbindung zum angegebenen Server und Port auf und das zweite horcht auf dem angegebenen Port (ist also ein Listener oder Server).

Was du daraus machst, ist dir überlassen. Du kannst z.B. eine Datei übertragen, indem du auf dem Ziel-Rechner in ein Shell-Fenster eingibst: copy tcp:999 ram:datei (horcht auf Port 999 und kopiert alles, was kommt in die Datei)
und auf dem Quell-Rechner: copy work:datei tcp:amiga2/999 (verbindet mit Port 999 auf dem entfernten Rechner und kopiert die Datei rüber).

Oder mit Newshell TCP:23 kannst du einen einfachen Telnet-Server aufbauen (ich glaube, das habe ich mal ausprobiert und es hat nicht funktioniert, aber es ist ja auch nur ein Beispiel).

Gruß Thomas

--
Email: thomas-rapp@web.de
Home: home.t-online.de/home/thomas-rapp/

[ - Antworten - Zitieren - Direktlink - ]

20.09.2004, 22:35 Uhr

Falcon
Posts: 3544
Nutzer
Hi nochmal,

@ Thomas:

ich bekomme folgende Fehlermeldung:

220 fwd06.sul.t-online.com T-Online ESMTP receiver fssmtpd ready.
+++ Error 8 in line 20: Unrecognized token

Zeile 8 ist die mit dem HELO-Kommando

Was läuft da schief ?

Danke,

Falcon.
--
Che-Hoa Yuin sagt:
Der Amiga kann alles, was man zum Arbeiten braucht...
... was er nicht kann, braucht man auch nicht !!!!!!!

Meine Homepage: http://www.elasticimages.de.vu

[ - Antworten - Zitieren - Direktlink - ]

20.09.2004, 22:38 Uhr

Robin
Posts: 1056
Nutzer
Danke :)

Das zwei Wochen vorher und ich haette mir
ne Menge Try & Error sparen koennen :)
Habe mir einen Server zum Fernsteuern meines
zweiten Pegs der einfach nur Befehle entgegen nimmt.

Mit dieser Methode geht das doch um einiges einfacher :D
--
Bild: http://my.morphosi.net/cgi-bin/mnet.pl?mode=forum&showsmilie=baby2 AMIGA-News Babysitter gesucht !

[ - Antworten - Zitieren - Direktlink - ]

21.09.2004, 00:00 Uhr

Falcon
Posts: 3544
Nutzer
Alles paletti, Thomas die einfachen Anführungszeichen waren Schuld.
Die gingen nach 'Copy & Paste' nach links statt nach rechts. Also nicht ALT + Ä.
hab ich korrigiert und lüppt.

Danke nochmals.

Falcon.
--
Che-Hoa Yuin sagt:
Der Amiga kann alles, was man zum Arbeiten braucht...
... was er nicht kann, braucht man auch nicht !!!!!!!

Meine Homepage: http://www.elasticimages.de.vu

[ - Antworten - Zitieren - Direktlink - ]

21.09.2004, 00:09 Uhr

Palgucker
Posts: 1342
Nutzer
@ Falcon

quote:

ich bekomme folgende Fehlermeldung:

220 fwd06.sul.t-online.com T-Online ESMTP receiver fssmtpd ready.
+++ Error 8 in line 20: Unrecognized token

Zeile 8 ist die mit dem HELO-Kommando

Was läuft da schief ?


Das PHP-Script tauscht die Anführungszeichen ' ' (ASCII 39) gegen ` ` (ASCII 96) aus. Das fällt einem selbst kaum auf, bringt Arexx aber zur Weißglut. Das hätte Dir Thomas aber auch sagen können, da er gerade im Thread mit dem Backslashproblem nochmal darauf hinwies.

mfg Palgucker

[ - Antworten - Zitieren - Direktlink - ]


-1- [ - Beitrag schreiben - ]


amiga-news.de Forum > Amiga, AmigaOS 4 > Suche eMail-Tool... [ - Suche - Neue Beiträge - Registrieren - Login - ]


.
Impressum | Datenschutzerklärung | Netiquette | Werbung | Kontakt
Copyright © 1998-2024 by amiga-news.de - alle Rechte vorbehalten.
.